Sonic Wall Status - Nagios plugin

#!/usr/local/bin/perl -w

use strict;
use Getopt::Long;
use lib "/usr/local/libexec/nagios";
use utils qw(%ERRORS &print_revision &support &usage );

#-clean-environment---------------------------------------------------------

$ENV{'PATH'}     = '';
$ENV{'BASH_ENV'} = '';
$ENV{'ENV'}      = '';

#-globals-------------------------------------------------------------------

my $PROGNAME = $0;

my $SONICWALLBASEMIB = '.1.3.6.1.4.1.8741';

my $opt_snmpwalk = '/usr/local/bin/snmpwalk';

my $opt_community = 'public';
my $opt_hostname  = '';

my $opt_debug    = 0;
my $opt_help     = 0;
my $opt_version  = 0;
my $opt_warning  = 0;
my $opt_critical = 0;

my $msg         = '';
my $exit_status = $ERRORS{'OK'};

my $USAGE = qq{
Usage:

  $PROGNAME [-d] [-v] [-?] [-h hostname] [-s community]

};

#-options-processing--------------------------------------------------------

GetOptions( 'debug|d+'      => \$opt_debug,
            'help|?'        => \$opt_help,
            'v|version'     => \$opt_version,
            'w|warning=i'   => \$opt_warning,
            'c|critical=i'  => \$opt_critical,
            's|community=s' => \$opt_community,
            'h|hostname=s'  => \$opt_hostname, );

if ($opt_help) { print $USAGE; exit $ERRORS{'OK'}; }
if ($opt_version) { printf '%s: %s', $PROGNAME, '$Revision: 1.13 $'; exit $ERRORS{'OK'}; }

die "hostname parameter required:\n$USAGE" if ( $opt_hostname eq '' );

#---------------------------------------------------------------------------
## flogster:/ # snmpwalk -OnQ -v2c -c public sonicfirewall .1.3.6.1.4.1.8741
## .1.3.6.1.4.1.8741.1.3.1.1.0 = 131250
## .1.3.6.1.4.1.8741.1.3.1.2.0 = 17734
## .1.3.6.1.4.1.8741.1.3.1.3.0 = 14
## .1.3.6.1.4.1.8741.1.3.1.4.0 = 20
## .1.3.6.1.4.1.8741.2.1.1.1.0 = "NSA 3600"
## .1.3.6.1.4.1.8741.2.1.1.2.0 = "70CAD38EF8BA"
## .1.3.6.1.4.1.8741.2.1.1.3.0 = "SonicOS Enhanced 6.1.1.5-19n"
## .1.3.6.1.4.1.8741.2.1.1.4.0 = "5.4.1.0"

my $snmpwalk = "$opt_snmpwalk -OnQ -v2c -c $opt_community $opt_hostname $SONICWALLBASEMIB";

my %MIBs = ();

open( SNMPWALK, "$snmpwalk|" ) or die "$!: $snmpwalk";
while (<SNMPWALK>) {
    if (m!^(\S+)\s+=\s+(.*?)$!soig) {
        my ( $key, $value ) = ( $1, $2 );
        $value =~ s!"!!soig;        # we don't want them
        print "KEY=$key VALUE=$value\n" if ($opt_debug);
        $MIBs{$key} = $value;
    }
}

my $connpercent = $MIBs{".1.3.6.1.4.1.8741.1.3.1.2.0"} / $MIBs{".1.3.6.1.4.1.8741.1.3.1.1.0"} * 100;
my $status      = 'OK';

# CRITICAL
if (    ( $MIBs{".1.3.6.1.4.1.8741.1.3.1.3.0"} > $opt_critical )
     || ( $MIBs{".1.3.6.1.4.1.8741.1.3.1.4.0"} > $opt_critical )
     || ( $connpercent > $opt_critical ) ) {

    $status = 'CRITICAL';
    $exit_status = $ERRORS{'CRITICAL'};

} elsif (    ( $MIBs{".1.3.6.1.4.1.8741.1.3.1.3.0"} > $opt_warning )
          || ( $MIBs{".1.3.6.1.4.1.8741.1.3.1.4.0"} > $opt_warning )
          || ( $connpercent > $opt_warning ) ) {

    $status = 'WARNING';
    $exit_status = $ERRORS{'WARNING'};

} else {

    $status = 'OK';
    $exit_status = $ERRORS{'OK'};

}

my $perfdata = sprintf "cpu=%d%%;;;; memory=%d%%;;;; currconn=%d;;;;%d",
  $MIBs{".1.3.6.1.4.1.8741.1.3.1.3.0"},
  $MIBs{".1.3.6.1.4.1.8741.1.3.1.4.0"},
  $MIBs{".1.3.6.1.4.1.8741.1.3.1.2.0"},
  $MIBs{".1.3.6.1.4.1.8741.1.3.1.1.0"};

printf "$status - CPU=%d%%, MEMORY=%d%%, CONNS=%d%%, model=%s, serial=%s, firmware=%s, rom=%s",
  $MIBs{".1.3.6.1.4.1.8741.1.3.1.3.0"},
  $MIBs{".1.3.6.1.4.1.8741.1.3.1.4.0"},
  $connpercent,
  $MIBs{".1.3.6.1.4.1.8741.2.1.1.1.0"},
  $MIBs{".1.3.6.1.4.1.8741.2.1.1.2.0"},
  $MIBs{".1.3.6.1.4.1.8741.2.1.1.3.0"},
  $MIBs{".1.3.6.1.4.1.8741.2.1.1.4.0"};

print '|' . $perfdata . "\n";

exit $exit_status;

__END__