Perl: check dns zone servers

given the output of "named-checkconf" parse the zones looking for forwarded zones and then test that those name servers actually do respond for that particular domain.

#!/usr/local/bin/perl -w
#
# $Header: /usr/local/etc/RCS/check-dns-zone-servers.pl-edit,v 1.12 2016/11/30 22:52:05 mwd Exp $
#
#------------------------------------------------------------------------

use strict;
use warnings;
use Data::Dumper;
use Getopt::Long qw(:config no_ignore_case bundling);

#------------------------------------------------------------------------
$Data::Dumper::Indent = 1;

#------------------------------------------------------------------------
my $opt_debug     = 0;
my $opt_all       = 0;
my $opt_log       = 0;
my $opt_checkconf = '/usr/local/bind/sbin/named-checkconf -p';
my $opt_dig       = '/usr/local/bind/bin/dig';
my $opt_digbind   = 'auto';                                          # set to 'auto' to have the script figure it out
my $opt_tag       = 'dns-zone-check';
my $opt_logger    = '/usr/bin/logger';

GetOptions(
    'debug|d+'      => \$opt_debug,
    'all|a!'        => \$opt_all,
    'log|l!'        => \$opt_log,
    'checkconf|c=s' => \$opt_checkconf,
    'dig|D=s'       => \$opt_dig,
    'digbind|B=s'   => \$opt_digbind,
    'tag|t=s'       => \$opt_tag,
    'logger|L=s'    => \$opt_logger,
);

#------------------------------------------------------------------------
my $config_data = '';
my %zones       = ();

#------------------------------------------------------------------------
#
# MAIN
#
# Get the output from named-checkconf
#
{
    # set slurp mode
    local $/ = undef;

    # open up offset file and get the data
    open( CONFIG_DATA, "$opt_checkconf|" ) or die "open: $!: $opt_checkconf";

    # read data
    $config_data = <config_data>;

    # close offset
    close(CONFIG_DATA);

    printf STDERR "CONFIG_DATA: %s\n", $config_data if ( $opt_debug > 6 );
}

#------------------------------------------------------------------------
#
# process the output from named-checkconf
#
{
    # options {
    # while ( $config_data =~ m@^(\s*)options\s+{(.*?)^\1};@smg ) {
    if ( $config_data =~ m@^options\s*{(.*?)^};@smg ) {
        my ($options_payload) = ($1);

        if ( $opt_digbind eq 'auto' ) {
            my $options_query_source = $1 if ( $options_payload =~ m!query-source\s+address\s+(\S+)!soig );
            $opt_digbind = $options_query_source || '';
        }
    } ## end while ( $config_data =~ m@^(\s*)options\s+{(.*?)^\1};@smg)

    # view "viewname" {
    while ( $config_data =~ m@^(\s*)view\s+(\S+)\s+{(.*?)^\1};@smg ) {

        my ( $view_leadingspace, $view, $view_payload ) = ( $1, $2, $3 );

        # clean up the zone name
        $view =~ s!^"|"$!!soig;

        # zone "nipt.telstra.com" {
        while ( $view_payload =~ m@^(\s+)zone\s+(\S+)\s+{(.*?)^\1};@smg ) {

            my ( $leadingspace, $zone, $payload ) = ( $1, $2, $3 );

            # clean up the zone name
            $zone =~ s!^"|"$!!soig;

            printf STDERR "view=%s leadingspace=%s zone=%s payload=%s\n", $view, $leadingspace, $zone, $payload
              if ( $opt_debug > 6 );

            if ( $payload =~ m!type\s+forward! ) {
                printf STDERR "VIEW (%s) FOUND FORWARDING ZONE (%s)\n", $view, $zone if ( $opt_debug > 6 );
            } elsif ( $payload =~ m!type\s+slave! ) {
                printf STDERR "VIEW (%s) FOUND SLAVE ZONE (%s)\n", $view, $zone if ( $opt_debug > 6 );
            } else {
                printf STDERR "VIEW (%s) NOT INTERESTED IN ZONE (%s)\n", $view, $zone if ( $opt_debug > 6 );
                next;
            }

            while ( $payload =~ m@(\d+\.\d+\.\d+\.\d+);@smg ) {

                my ($ip) = ($1);

                printf STDERR "VIEW (%s) FOUND NAME SERVER (%s) FOR ZONE (%s)\n", $view, $ip, $zone if ( $opt_debug > 6 );

                $zones{"$view;$zone"} .= $ip . ":";

            } ## end while ( $payload =~ m@(\d+\.\d+\.\d+\.\d+);@smg)

        } ## end while ( $view_payload =~ ...)
    } ## end while ( $config_data =~ m@^(\s*)view\s+(\S+)\s+{(.*?)^\1};@smg)
}

#------------------------------------------------------------------------
foreach my $key ( sort keys %zones ) {

    printf STDERR "KEY=%s VALUE=%s\n", $key, $zones{$key} if ( $opt_debug > 6 );

    my $iplist = $zones{$key};
    $iplist =~ s!:$!!soig;

    my ( $view, $zone ) = ( $1, $2 ) if ( $key =~ m!^(\S+);(\S+)$! );

    foreach my $ip ( split( m!:!, $iplist ) ) {
        printf STDERR "VIEW (%s) TESTING SERVER IP %s FOR ZONE %s\n", $view, $ip, $zone if ( $opt_debug > 6 );

        my $bindopt = ( $opt_digbind eq '' ) ? '' : "-b $opt_digbind";

        # print STDERR qq{my $bindopt = ( $opt_digbind eq '' ) ? '' : "-b $opt_digbind";\n};

        #  dig -t any -q tresrie.d.v.au @10.4.0.50
        my $digcmd = sprintf "%s %s -t any -q %s @%s",    $opt_dig, $bindopt, $zone, $ip;
        printf STDERR "VIEW (%s) DIGCMD = %s\n", $view, $digcmd if ( $opt_debug > 6 );

        my $dig_result = qx{ $digcmd };

        my $dig_status = $1 if ( $dig_result =~ m!status:\s+(\S+)!soig );
        $dig_status ||= 'NOANSWER';
        $dig_status =~ s!\W+$!!soig;

        next if ( ( $dig_status eq 'NOERROR' ) && !$opt_all );

        printf STDERR "VIEW (%s) SERVER (%s) ZONE (%s) STATUS (%s)\n", $view, $ip, $zone, $dig_status if ( $opt_debug > 0 );

        my $msg = sprintf "view=%s zone=%s server=%s status=%s", $view, $zone, $ip, $dig_status;

        if ($opt_log) {
            qx{ $opt_logger -t '$opt_tag' '$msg' };
        } else {
            printf "%s\n", $msg;
        }

    } ## end foreach my $ip ( split( m!:!...))
} ## end foreach my $key ( sort keys...)

#------------------------------------------------------------------------
exit 0;

__END__






unix:/ # crontab -l
#-------------------------------------------------------------------------
#
# Test that the DNS Servers for all of the zones we use are responsive
#
45 * * * * ( /usr/local/etc/check-dns-zone-servers.pl -a -l -B 10.0.0.1 ) > /var/log/check-dns-zone-servers.log 2>&1
#
#-------------------------------------------------------------------------